# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Leonid B <leonid dot bloch at esrf dot fr>
# Upstream contact: silx at esrf dot fr
pkgname=python-fabio
_pkgname=fabio
pkgver=0.11.0
pkgrel=1
pkgdesc="I/O library for images produced by 2D X-ray detectors."
arch=('i686' 'pentium4' 'x86_64')
url="http://www.silx.org"
license=('MIT' 'LGPL' 'Apache')
_pinned_dependencies=(
  'glibc>=2.31'
)
depends=(
  "${_pinned_dependencies[@]}"
  'python<3.10'
  'python>=3.9'
  'python-numpy')
makedepends=(
  'cython'
  'python-setuptools')
optdepends=('python-pyqt4: for the fabio_viewer program')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/silx-kit/${_pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('70e4e45000046cdd13438ea3be3c92d438f4946ea118b3c4339efdb8456cfcc1ac3a64c7724f20a299a2739a9191a2fc0b009c3681e052a5fcf16b5cd5d7dc86')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py build
}

package_python-fabio() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}/" --optimize=1
  install -D copyright "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}