# Maintainer: Erich Eckner <arch at eckner dot net>
pkgname=perl-perlio-layers
_pkgname='PerlIO-Layers'
pkgver=0.011
pkgrel='6'
_distdir="${_pkgname}-${pkgver}"
pkgdesc="Querying your filehandle's capabilities"
arch=('x86_64' 'i686')
url="https://github.com/Leont/perlio-layers"
license=('GPL' 'PerlArtistic')
depends=(
  'perl>=5.8.1'
  'perl-carp'
  'perl-exporter>=5.57'
  'perl-scalar-list-utils'
  'perl-xsloader')
makedepends=(
  'perl-data-dumper'
  'perl-io'
  'perl-module-build>=0.3601'
  'perl-pathtools'
  'perl-test-simple>=0.82')
checkdepends=(
  'perl-pod-coverage-trustpod'
  'perl-test-pod'
  'perl-test-pod-coverage'
  'perl-test-simple'
)
source=("http://search.cpan.org/CPAN/authors/id/L/LE/LEONT/${_distdir}.tar.gz")
sha256sums=('1d77e164aa5d5d24699a5479a423abdc1b07973fbe5a22d304fef2c560254b42')

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
      MODULEBUILDRC=/dev/null

    cd "${srcdir}/${_distdir}"
    perl Build.PL
    perl Build
  )
}

check() {
  cd "${srcdir}/${_distdir}"
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    export RELEASE_TESTING=1
    perl Build test
  )
}

package() {
  cd "${srcdir}/${_distdir}"
  perl Build install
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}