# Maintainer: Erich Eckner <arch at eckner dot net>

pkgname='perl-mojolicious'
pkgver=7.70
pkgrel=1
pkgdesc='Web development toolkit'
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=(
  'perl>=5.10.1'
  'perl-io-socket-ip>=0.37'
  'perl-json-pp>=2.27103'
  'perl-pod-simple>=3.09'
  'perl-time-local>=1.2')
makedepends=(
  'perl-extutils-makemaker')
checkdepends=(
  'perl-ev>=4'
  'perl-io-socket-socks>=0.64'
  'perl-io-socket-ssl>=1.94'
  'perl-role-tiny'
  'perl-test-pod'
  'perl-test-pod-coverage')
url='https://metacpan.org/release/Mojolicious'
_distdir="Mojolicious-${pkgver}"
source=("https://cpan.metacpan.org/authors/id/S/SR/SRI/${_distdir}.tar.gz")
sha512sums=('2cda5b378d5c1899d78c199c7f1d3439a6fd697ab885bb4d337270256534ec68f9d73267199a6f72e9677049cf9cd6f239451cac31aebcf4743229419a82dd8b')

prepare() {
  cd "$srcdir/$_distdir"
  rm t/mojo/websocket_proxy_tls.t
}

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
      MODULEBUILDRC=/dev/null

    cd "$srcdir/$_distdir"
    perl Makefile.PL
    make
  )
}

check() {
  cd "$srcdir/$_distdir"
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    export TEST_EV=1
    export TEST_HYPNOTOAD=1
    export TEST_IPV6=1
    export TEST_MORBO=1
    export TEST_ONLINE=1
    export TEST_POD=1
    export TEST_PREFORK=1
    export TEST_SOCKS=1
    export TEST_SUBPROCESS=1
    export TEST_TLS=1
    export TEST_UNIX=1
    make test
  )
}

package() {
  cd "$srcdir/$_distdir"
  make install

  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et: