# Maintainer: Erich Eckner <arch at eckner dot net>
# Contributor: Piotr Rogoża <piotr dot r dot public at gmail dot com>

pkgname=perl-file-find-object
pkgver=0.3.2
pkgrel='5'
_author="S/SH/SHLOMIF"
_distdir="File-Find-Object-v${pkgver}"
pkgdesc="File::Find::Object - An object oriented File::Find replacement"
arch=('any')
url="http://search.cpan.org/dist/File-Find-Object/"
license=('GPL' 'PerlArtistic')
provides=(
  'perl-file-find-object-base=0.3.2'
  'perl-file-find-object-deeppath=0.3.2'
  'perl-file-find-object-pathcomp=0.3.2'
  'perl-file-find-object-result=0.3.2'
  'perl-file-find-object-toppath=0.3.2')
depends=(
  'perl>=5.8.0'
  'perl-carp'
  'perl-class-xsaccessor'
  'perl-parent'
  'perl-pathtools'
  'perl-scalar-list-utils')
makedepends=(
  'perl-extutils-makemaker'
  'perl-file-path'
  'perl-file-temp'
  'perl-io'
  'perl-lib'
  'perl-module-build>=0.28'
  'perl-test-simple')
checkdepends=(
  'perl'
  'perl-cpan-changes'
  'perl-pod-coverage-trustpod'
  'perl-test-kwalitee-extra'
  'perl-test-pod'
  'perl-test-pod-coverage'
  'perl-test-simple'
  'perl-test-trailingspace'
)
options=(!emptydirs)
source=("http://search.cpan.org/CPAN/authors/id/$_author/${_distdir}.tar.gz")
sha512sums=('58ca07083da520aee03945259ac89b6b584728d89ad52aea1a6f19a14da73fc92fcfc46c01656130d64fbc9fc9e4b1c5ef56274f30ebe3711972235dd8945956')

build(){
  cd "$srcdir/${_distdir}"

  # Setting these env variables overwrites any command-line-options we don't want...
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps \
    PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
    PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
    MODULEBUILDRC=/dev/null

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    /usr/bin/perl Makefile.PL
    make
  # If using Build.PL
  elif [ -r Build.PL ]; then
    /usr/bin/perl Build.PL
    perl Build
  fi
}
check(){
  cd "$srcdir/${_distdir}"

  export AUTHOR_TESTING=1
  export RELEASE_TESTING=1

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    make test
  # If using Build.PL
  elif [ -r Build.PL ]; then
    perl Build test
  fi
}
package(){
  cd "$srcdir/${_distdir}"

  # If using Makefile.PL
  if [ -r Makefile.PL ]; then
    make install
  # If using Build.PL
  elif [ -r Build.PL ]; then
    perl Build install
  fi

  # remove perllocal.pod and .packlist
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}